coretan tentang autocad dan excel

April 11, 2014

[XLS-SVY-22]: Hitungan Azimuth dari Poligon Tertutup

Filed under: Excel — cadex @ 15:45
Referensi : Kumpulan Rumus
Platform :  
Lokasi File :  

Pada gambar pengukuran poligon tertutup di bawah, azimuth awal dalam poligon tertutup menggunakan nilai pendekatan karena koordinat Titik-1 belum mempunyai nilai tetap atau Fix. Jika setelah pengukuran poligon tersebut ada pengukuran titik kontrol horisontal yang lebih teliti, misalnya dengan GPS Geodetic, di titik BM.1 dan Titik-1, maka nilai azimuth fix atau tetap dari titik BM.1 ke Titik-1 dapat dihitung.

Apabila ternyata titik yang diukur dengan GPS Geodetic adalah di titik BM.1 dan Titik-4, maka azimuth awal tidak bisa dihitung secara langsung

image

Tahap perhitungan azimuth dari poligon tertutup adalah:

Pertama, poligon tertutup dihitung dengan input koordinat azimuth pendekatan dan koordinat pendekatan :

Apabila hasil Ketelitian Sudut dan Ketelitian Linear memenuhi kriteria atau persyaratan yang diminta, maka dilanjutkan tahap berikutnya. Jika tidak memenuhi, maka perlu dicek lagi pengukuran dan input data poligonnya.

Kedua, titik awal poligon (BM.1) diganti dfengan titik tetap sehingga secara otomatis Microsoft Excel menghitung koordinata Titik-4.

Koordinat Titik-4 ini masih merupakan koordinat pendekatan. Hasil perbandingan azimuth dari BM.1 ke "Titik-4 Fix" dengan azimuth dari BM.1 ke "Titik-4 Pendekatan" akan didapatkan nilai koreksi azimuth pendekatan.

Cell

Rumus

Keterangan

[AA7]

 

koordinat (X) Titik-4 hasil hitungan poligon

[AB7]

 

koordinat (Y) Titik-4 hasil hitungan poligon

[AC6]

=DEGREES(ATAN2((AB7-AB5),(AA7-AA5)))
+IF(ATAN2((AB7-AB5),(AA7-AA5))<0,360)

azimuth dari BM.1 ke "Titik-4 Pendekatan"

[AD7]

 

koordinat (X) "Titik-4 Fix"

[AE7]

 

koordinat (Y) "Titik-4 Fix"

[AF6]

=DEGREES(ATAN2((AE7-AE5),(AD7-AD5)))
+IF(ATAN2((AE7-AE5),(AD7-AD5))<0,360)

azimuth dari BM.1 ke "Titik-4 Fix"

[AG6]

=AF6-AC6

koreksi Azimuth Awal

[AH6]

 

Azimuth Awal

[AI6]

=AH6+AG6

Azimuth Awal setelah dikoreksi

[AJ6:AL6]

 

konversi derajat decimal ke derajat, menit, detik

Setelah didapatkan nilai azimuth awal dikoreksi, hitungan poligon tertutup menjadi :

=selamat mencoba=

April 10, 2014

[XLS-PMG-07]: Menghitung upah lembur dengan excel (Kep Men. NOMOR KEP. 102/MEN/VI/2004) Bagian 2 (Revisi 10 April 2014)

Filed under: Excel, Project Management — Tags: , , — cadex @ 16:53

Referensi

:

[GEN-PMG-04]:Menghitung Upah Lembur dengan Excel (Kep Men. NOMOR KEP. 102/MEN/VI/2004)

Platform

:

Excel 2007

Lokasi File

:

 

Pada posting [GEN-PMG-04]:Menghitung Upah Lembur dengan Excel (Kep Men. NOMOR KEP. 102/MEN/VI/2004) telah diuraikan cara menghitung lembur atau menentukan faktor pengali lembur untuk 5 hari kerja. Kali ini akan diuraikan cara menghitung faktor pengali lembur untuk 6 hari kerja. Hitungan kali ini memasukkan hari kerja adalah Senin s.d Sabtu dengan asumsi hari Sabtu adalah hari pendek. Jam kerja normal senin sampai sabtu adalah 7 jam, sedangkan untuk hari pendek adalah 5 jam. Kutipan dari Keputusan Menteri Pasal 11 :

Cara perhitungan upah kerja lembur sebagai berikut :
a. Apabila kerja lembur dilakukan pada hari kerja : a.1. untuk jam kerja lembur pertama harus dibayar upah sebesar 1,5 (satu setengah) kali upah sejam; a.2. untuk setiap jam kerja lembur berikutnya harus dibayar upah sebesar 2(dua) kali upah sejam.
b. Apabila kerja lembur dilakukan pada hari istirahat mingguan dan/atau hari libur resmi untuk waktu kerja 6 (enam) hari kerja 40 (empat puluh) jam seminggu maka : b.1. perhitungan upah kerja lembur untuk 7 (tujuh) jam pertama dibayar 2 (dua) kali upah sejam, dan jam kedelapan dibayar 3 (tiga) kali upah sejam dan jam lembur kesembilan dan kesepuluh dibayar 4 (empat) kali upah sejam. b.2. apabila hari libur resmi jatuh pada hari kerja terpendek perhitungan upah lembur 5 (lima) jam pertama dibayar 2 (dua) kali upah sejam, jam keenam 3(tiga) kali upah sejam dan jam lembur ketujuh dan kedelapan 4 (empat) kali upah sejam. c. Apabila kerja lembur dilakukan pada hari istirahat mingguan dan/atau hari libur resmi untuk waktu kerja 5 (lima) hari kerja dan 40 (empat puluh) jam seminggu, maka perhitungan upah kerja lembur untuk 8 (delapan) jam pertama dibayar 2 (dua) kali upah sejam, jam kesembilan dibayar 3(tiga) kali upah sejam dan jam kesepuluh dan kesebelas 4 (empat) kali upah sejam.

ayat a, b atau text berwarna biru adalah sebagai dasar untuk perhitungan lembur. Seperti posting sebelumnya [GEN-PMG-04]:Menghitung Upah Lembur dengan Excel (Kep Men. NOMOR KEP. 102/MEN/VI/2004), list hari libur dibuat terlebih dahulu. List hari libur di posting kali ini menggunakan named range dengan type dynamic, bukan static range yang telah dijelaskan sebelumnya. Static Named range mengharuskan kita untuk memlilih range terlebih dahulu sebelum mendefinisikan range, dimensi range (records) akan bertambah jika penambahan data ada di tengah static range atau dengan cara insert rows. Sedangkan Dynamic Named Range, range akan otomatis berubah dimensinya atau bertambah data secara otomatis jika record ditambahkan ataupun diiinsert. Tahapan-tahapan yang dibuat di bawah dikerjakan engan Excel 2007, jika Anda menggunakan excel versi lain, silahkan disesuaikan. Tahapan pembuatan dynamic range adalah :

  • Buat list daftar hari libur di sheet tersendiri, misalnya daftarnya sebagai berikut :

  • Pada menu group [Formula], pilih [Define Name]

Masukkan nama range, misal "_LiburNasional" Refers to: =OFFSET($B$1,1,-1,COUNT(A:A),1) maksud dari rumus di atas adalah :— membuat range dengan acuan $B$1, turun 1 baris, kemudian ke kiri 1 kolom. Hasil dari perintah ini adalah $B$2 — dilanjutkan dari B2, membuat range dengan tinggi sebanyak angka atau tanggal di kolom A:A atau COUNT(A:A) dengan lebar 1 kolom. Jika tanggal hari libur di kolom A ada 20 tanggal, maka  akhir dari perintah ini adalah $B$2:$B$20

  • Buat tabel kode hari kerja yaitu kode hari yang membedakan hari normal, sabtu, minggu, hari libur nasional dan hari libur di hari pendek (sabtu)

Buat ‘static named range’ dengan nama yang telah didefinisikan di kolom ‘named range':

— block [J2:K5]

– dari menu [Formulas], pada group [Define Names], pilih [Create from Selection]

– Pada pilihan ‘Create names from values in the’ , centang (check) hanya di [Right Column]

  • Memberi kode hari di list tanggal absensi. misal tabel disusun sebagai berikut:

Revisi 10 April 2014

Kolom A dan B diisi manual, sedangkan untuk kolom C:H diisi dengan rumus excel. Rumus untuk kolom C:H adalah: Catatan: rumus atau formula ditulis dalam satu baris dalam excel



Cells

Rumus

Keterangan

[C2]

=IF(COUNTIF(_LiburNasional,A2)>0,IF(WEEKDAY(A2,2)=6,3,2),IF(WEEKDAY(A2,2)=6,1,IF(WEEKDAY(A2,2)=7,2,0)))

menentukan kode hari berdasarkan tanggal di A2

[D2]

=(C2=Normal)*(B2>7)+(C2=Sabtu)*(B2>5)

jam lembur x 1.5

[E2]

=IF((C2=Normal)*(B2>8),B2-8,IF((C2=Sabtu)*(B2>6),B2-6,IF(C2=LiburMinggu,IF(B2<7,B2,7),IF(C2=SabtuLibur,IF(B2<5,B2,5)))))+0

jam lembur x 2

[F2]

=(C2=LiburMinggu)*(B2>7)+(C2=SabtuLibur)*(B2>5)

jam lembur x 3

[G2]

=IF((C2=LiburMinggu)*(B2>8), B2-8,IF((C2=SabtuLibur)*(B2>6),B2-6))*1

jam lembur x 4

[H2]

=SUMPRODUCT(D2:G2,$D$1:$G$1)

total faktor pengali

Copy Rumus [C2:H2] ke bawah..

 

Silahkan download file revisi untuk contoh sample aplikasi perhitungan gaji lengkap dengan hitungan lembur untuk 6 hari kerja. File hasil download adalah simulasi perhitungan dari input daftar karyawan & unit price gaji, list hari libur, form resume absensi dan contoh form slip gaji. Jika ada kesalahan perhitungan, jangan sungkan-sungkan untuk memberi masukan.

==selamat mencoba==

March 15, 2014

[XLS-PMG-08]: Update Hari Libur di Microsot Project dengan VBA Excel

Filed under: Excel, Project Management — cadex @ 14:47
Referensi :
Platform : Microsoft Excel dan Microsoft Project
Lokasi File :  download

Salah satu setting yang perlu diperhatikan dalam penggunaan Microsoft Project (MSProject) adalah memasukkan Hari Libur Nasional ke dalam kalender. Apabila proyek yang akan dilaksanakan telah disepakati atau diusulkan bahwa di hari Libur Nasional adalah bukan hari kerja, maka tanggal-tanggal hari libur tersebut harus dimasukkan dalam list exceptions di calendar yang akan dipakai.

Contoh Kalender (Calendar) yang belum dimasukkan daftar hari libur adalah:

Daftar hari libur bisa dimasukkan secara manual di tab Exceptions dengan memasukkan nama hari libur diikuti dengan tanggal awal libur dan akhir libur.

Apabila list hari libur tersimpan dalam Microsoft excel seperi di bawah:

Maka dengan bantuan Visual Basic Application for Excel (VBA Excel), proses update calendar di MSProject bisa dilakukan secara otomatis.

Berikut adalah code VBA Excel yang dimaksud:

Sub UpdateHariLiburNasional()

‘Code berikut berfungsi untuk menambahkan hari libur nasional di microsoft project (MSProject).

‘Pada visual basic editor direferensikan ke Microsoft Project Library agar dapat mengakses object di ‘Microsoft Project.

‘karena saya menggunakan microsoft project 2010, maka nama referensinya : Microsoft Project 14.0 ‘Object Library

‘untuk MSProject versi yang lain, nama referensi hanya berbeda pada angka di belakang tulisan ‘”Microsoft Project XX.X”

‘Alokasi memory untuk object aplikasi MSProject dan Project yang aktif

Dim msApp As MSProject.Application, msPro As Project

‘akan muncul pesan error jika program MSProject belum dijalankan

On Error Resume Next

‘set ke object aplikasi MSProject

Set msApp = GetObject(, “MSProject.Application”)

If Err.Number Then

Err.Clear

MsgBox ” Program Microsoft Projet Belum diaktifkan”

Exit Sub

End If

‘set ke object projek yang aktif

Set msPro = msApp.ActiveProject

‘alokasi memory untuk object kalender

Dim zCal As Calendar, nmCalendar As String

‘set ke object kalender

‘nama kalender yang akan diisi hari libur pada contoh kali ini adalah “Standard”

‘jika nama kalender tidak ditemukan, maka keluar prosedur

nmCalendar = “Standard”

On Error Resume Next

Set zCal = msPro.BaseCalendars(nmCalendar)

If Err.Number Then

Err.Clear ‘bersihkan error

MsgBox “Kalender ” & nmCalendar & ” tidak ada”, vbCritical

GoTo BersihkanAplikasiMSProject

Exit Sub ‘keluar prosedur

End If

‘membaca list tanggal pada Microsoft Excel di sheet yang aktif

‘informasi tangal ada di kolom A, sedangkan informasi keterangan ada di kolom B

‘data dibaca dimulai dari baris ke-dua

Dim rgTanggal As Range, rg As Range

‘set range tanggal di aktif sheet

Set rgTanggal = Range(Range(“a2″), Range(“a2″).End(xlDown))

‘membaca tanggal dan keterangan hari libur

For Each rg In rgTanggal

‘menambahkan exception di object calender

zCal.Exceptions.Add _

Type:=pjDaily, _

Start:=rg.Value, _

Finish:=rg.Value, _

Name:=rg.Offset(, 1).Value

Next rg

BersihkanAplikasiMSProject:

Set msApp = Nothing

End Sub

Seperti telah tercatat di code VBA Excel di atas, syarat-syarat sebelum menjalan VBAExcel di atas adalah:

  1. VBA sudah direferensikan ke object MSProject Library
  2. Program Microsoft Project dan Microsft Excel harus dibuka bersamaan.
  3. Nama Calender yang dipilih harus sudah ada di MSProject yang aktif.

Contoh calendar yang telah diupdate:

Selamat mencoba..

December 30, 2013

Menghitung Luas Bidang Tanah dengan Autocadmap

Filed under: Excel — cadex @ 15:54

Referensi

:

 

Platform

:

AutocadMap

Lokasi File

:

tidak tersedia

 

Luas bidang tanah yang telah tergambar di autocadmap bisa dihitung luasnya dengan menggunakan fasilitas topologi. Ada tiga jenis topologi dalam autocadmap yaitu topology garis / network, topology titik /point dan topologi polygon. Jenis topology polygon adalah topology yang sesuai untuk proses perhitungan luas karena dalam pembuatan topologi polygon salah satu informasi yang didapat adalah luasan polygon tertutup.

Melalui “Topology Query”, hasil topology tersebut bisa diexport ke text (ascii) file untuk dibuatkan daftar atau list informasi luas untuk tiap id bidang dan juga bisa menampilkan text informasi luas secara otomatis di autocadmap.

Agar memudahkan saat proses editing gambar dalam pembuatan topologi, berikut adalah syarat-syarat gambar yang akan dibuat topology polygon berdasarkan pengalaman saya:

  1. Pembatas bidang tersebut terletak di layer yang sama atau dalam satu layer
  2. Pembatas bidang bertipe line atau polyline atau lwpolyline dua (2) dimensi
  3. Tiap satu bidang tanah mempunyai satu centroid atau kode bidang bisa berupa text atau blok attribute
  4. Pembatas bidang harus tertutup

Berikut contoh gambar beberapa bidang tanah yang akan dihitung luasannya dengan topology polygon:

Syarat #1: Cek pembatas bidang terletak dalam satu layer

Pilih salah satu garis pembatas bidang kemudian rubah warna layernya sehingga warna garis berbeda dengan pembatas yang lain. Dalam contoh gambar ini, layer pembatas bidang adalah : 020100. Layer tersebut kemudian diberi warna merah.

Garis yang ditandai kuning adalah bukan pembatas bidang atau pembatas bidang tetapi belum atau tidak complete. Rubah layer garis yang ditandai tersebut menjadi layer lain.

Text berwarna merah adalah text yang seharusnya bukan menjadi pembatas bidang sehingga text tersebut harus dikeluarkan dari layer pembatas bidang.

 

Gambar setelah editing layer batas bidang:

Syarat #2: Pembatas bidang berupa LINE, POLYLINE atau LWPOLYLINE dua (2) dimensi

Telah dijelaskan di atas bahwa layer untuk object pembatas bidang adalah 020100 sehingga object dalam layer tersebut harus berisi object LINE, POLYLINE atau LWPOLYLINE. Cara mengecek type object dalam sebuah layer adalah sebagai berikut:

2.1. Ketik pada command: QSELECT

lakukan setting atau pilihan

Properties: Layer

Operators: = Equals

Value: 020100

kemudian click [OK]

 

Semua object dalam layer 020100 akan terpilh (selected)

2.2. Ketik lagi pada command:QSELECT

lakukan setting

Apply to: Current selection

Click object type

 

Ternyata dalam layer yang 020100 masih ada object lain selain line dan Polyline yaitu Text dan Point

 

Pilih Object Type Text kemudian rubah layernya

 

2.3. Ulang langka 2.2. sehingga object type di layer 020100 hanya terdiri dari Multiple, LINE dan POLYLINE

 

Syarat #3: Tiap satu bidang harus mempunyai satu (1) id sebagai centroid.

Pada contoh gambar di atas ID bidang adalah berupa text yang berisi lima digit angka yang diletakkan di layer 080201. Rubah warna layer ini sehingga mudah untuk diidentifikasi kemudian lakukan checking type object yang ada pada layer ini. Karena ID bidang berupa text, maka pada layer ini harus terdiri dari object yang berupa text saja. Lakukan langkah-langkah yang telah diuraikan di atas untuk mengecekan object.

Jika sudah dilakukan checking type object, matikan semua layer kecuali layer batas bidang (020100) dan layer id (080201)

Syarat #4: Pembatas bidang harus tertup.

Bagian yang ditandai biru adalah bidang yang belum tertutup sehingga diperlukan editing lebih lanjut pada pembatas bidang tersebut. Dalam gambar ini proses editing yang dilakukan adalah memotong (break) garis lama yang sebelumnya ada di layer 040100 menjadi layer 020100 (layer batas bidang).

Gambar menjadi:

Gambar di atas sudah siap dilakukan proses pembuatan polygon topology dengan tahapan sebagai berikut:

  1. Cleaning Gambar
    1. Ketik pada command: MAPCLEAN
    • Pilih [Select All]
    • Pada Layers masukkan layer batas bidang (120100)
    • Click [Next

    1. Clean up options, pilih cleanup actions:
    • Delete Duplicates: untuk menghapus garis atau polyline yang duplicates
    • Erase Short Objects: menghapus object garis yang sangat pendek
    • Break Crossing Object: otomatis break garis jika saling berpotongan
    • Snap Clustered Nodes: node yang berdekatan akan otomatis bersatu.

     

    click [Next]

    1. Pilih [Modify original objects] di [Cleanup Method]
    2. Click [Finish]

     

  2. Pembuatan Topologi
    1. Ketik pada command: MAPWSPACE

      kemudian pilih [On]

      Setelah proses ini, task pan autocadmap akan ditampilkan seperti gambar di samping

       

      Pilih Tab [Map Explorer]

    1. Click kanan [Topologies], kemudian pilih [Create]
     
    1. Pilih Topology Type: Polygon
      1. Topology Name (misal):bd
      2. Click tombol [Next]
     
    1. Pilih Select All
      1. Click simbol layer, kemudian pilih layer pembatas bidang 020100
      2. Click tombol [Next]

    1. Select Nodes. Pilih Select All
      1. Click tombol [Next]
     
    1. Create New Nodes, uncheck pilhan create new nodes
      1. Click [Next]

    1. Select Centroids. Pilh Select All
      1. Click simbol layer, kemudian pilih layer yang berisi text di bidang (080201)
      2. Click [Next]

    1. Create New Centroid. Uncheck pilihan create missing centroids
      1. Click [Next]

    1. Error Markers:
    • Polygon tanpa ID ditandai dengan Rhombus warna Cyan
    • Polyon yang saling berpotongan ditandai dengan octagon warna Green
    • Polygon dengan ID lebih dari satu ditandai dengan square warna red
    • Polygon yang tidak menutup tidandai dengan triangle warna yellow

    Clck [Finish]

    1. Setelah click [Finish], jika ada kesalahan polygon, autocadmap memunculkan kotak peringatan.

       

      Pada contoh kali ini diidentifikasi sebagai polygon yang saling berpotongan atau (intersections detected)

       

      click [Close]

       

      kemudian cari symbol octagon yang berwarna green atau hijau.

    1. Pada gambar disamping ternyata ada double polygon atau batas bidang yang bertumpuk.

       

      Saya hapus bidang yang double tersebut sehingga tidak ada double

    1. Ulangi langkah 1-18

       

      setelah diulang langkah di atas, pesan error yang muncul adalah Link doesn’t belong to any polygon

       

      Error ini menandakan bahwa ada polygon yang belum menutup atau belum ada break line di perpotongan garis. Error ditandai dengan segitiga warna kuning.

    1. Contoh error dan koreksinya:
    • Ditemukan polygon yang tidak menutup sempurna (lingkaran hijau) sehingga menyebabkan polygon terbuka.
    • Lakukan trim garis di lingkaran hijau

    1. Gambar setelah dikoreksi

    1. Contoh garis yang harus di-break
    • Pada gambar disamping garis yang terpilih harus dipecah atau break
    • Gunakan perintah break sehingga garis yang terpilih menjadi dua garis seperti gambar di bawahnya.’

    setelah diedit:

    1. Jika tidak ada error, maka ada tambahan topology di map explorer

    1. Untuk mengetahui informasi luas dari hasil topology polygon:
    • Click icon atau ketik di command: ADEEDITDATA
    • Pilih ID bidang (text di layer 080201)

     

Sampai pada tahap ini proses pembuatan topologi telah selesai. Tahap selanjutnya adalah mengexport list informasi luas tersebut ke text file melalui tahapan berikut:

  1. Klik kanan nama topology di map explorer kemudian pilih Analysis>>Topology Query

  1. Lakukan setting di Topology Query:
  • Topology Type: None
  • Click [Define Query]
 
  1. Set di [Define Query Topology]:
  • Click [Location], kemudian pilih [Boundary Type]: All
  • [Query Mode]: Report
  • Click [Options]

  1. Pada [Output Report Options], click [Expression…]
  • Pada group [Properties], pilih String] kemudian clik [OK] lalu click [Add]
  • Click lagi [Expression…], kemudian di bawah group [Topologies] pilih Topology Polygon:bd
  • Pada group [Polygon Centroid], pilih [Area]
  • Click [OK]
  • Clik [Add]
  • Click [Browse], kemudian pilih folder tempat menyimpan hasil report query

  1. Output Report Options menjadi

Hasil report akan disimpan dalam file peta_bidang.txt dalam format comma delimeted dengan susunan kolom pertama (.STRING) adalah nomer ID Bidang dan kolom kedua (.AREA@TPMCNTR_bd) adalah informasi luas dari topology bd

  • Click [OK]
  • Click [Execute Query]

  1. Hasil report query di file peta_bidang.txt
  • File tersebut bisa juga dibuka dengan mirosoft excel ataupun diimport ke Microsoft access atau file database lainnya

 

Untuk menampilkan text informasi luas di autocadmap lakukan langkah-langkah seperti berikut:

  1. Buat Layer baru khusus untuk text informasi luas. Misal txtLuas
 
  1. Lakukan seperti langkah 1 & 2 seperti di atas
 
  1. Setting di [Define Query Topology]
  • Click [Clear Query] untuk menghilangkan query sebelumnya
  • Click [Location]>>[Boundary Type]:All
  • [Query Mode]: Draw
  • Check opsi sebelah kiri [Alter Properties…]
  • Click [Alter Properties..]
  • Pada group [Select Property], click [Text]

  1. Seeting di [Define Text]:
  • Click [Expression]
  • Pada [Text Value Expression] pilih [Topologies]>>[Polygon:bd]>>[Polygon Centroid]>>[Area]
  • Click [OK]

     

bd adalah nama topology polygon yang telah dibuat.

 

Hasil Text Value disamping adalah mencetak informasi luas di layer:txtLuas dengan banyaknya angka di belakang tanda desimal sebanyak 13 digit seperti seperti hasil report query pada langkah 6 di atas.

  1. Merubah tampilan text luas.
  • Rubah text value seperti petunjuk di samping
  • Click [OK]

Text value semula

:AREA@TPMCNTR_bd

 

Menjadi

(STRCAT “LUAS : ” (FIX :AREA@TPMCNTR_bd) ” M2″)

 

Property Alteration menjadi:

  1. Click [Execute] di [Define of Query Topology]
  • Tampilan setelah ada informasi luas
  • Text luas berhimpit dengan text id bidang

  1. Agar tampilan luas berada di bawah nomor ID bidang. Lakukan Langkah berikut:
  • Ketik di command:QSELECT
  • Properties: Layer
  • Operator: = Equal
  • Value: txtLuas
  • Click [OK]
  • Ketik command: MOVE
  • Geser ke Bawah

 

 

Posting berikutnya akan dicoba untuk me-link-an antara database yang tersimpan dalam database access atau excel yang berisi daftar nama dan informasi lain sehingga dalam file autocadmap bisa disajikan peta tematik tematik yang lebih informative.

===Selamat mencoba===

 

December 28, 2013

[XLS-SVY-13]: Plotting Cross Section dari Excel ke AutoCAD Versi 1.1

Filed under: Excel — cadex @ 01:20

Originally posted on coretan tentang autocad dan excel:

Referensi : [XLS-SVY-007]: Plotting Cross Section dari Excel ke AutoCAD
Platform : Autocad , Excel 2007/Excel 2003
Lokasi File :

Pada posting [XLS-SVY-007]: Plotting Cross Section dari Excel ke AutoCAD, telah diuraikan tahapan untuk membuat gambar cross section dari file excel.

Posting kali ini akan saya akan mencoba untuk versi plotting cross section dari excel ke autocad dengan beberapa fasilitas tambahan. Berikut adalah snap shot program vba-excel / macronya:

image

Fasilitas tambahan seperti yang ditampilkan di atas adalah:

  • Ada tambahan custom menu bar, sehingga tidak lagi menggunakan menu run macro
  • Ada setting parameter skala horizontal, skala vertikal, tinggi huruf dan tinggi band (informasi baris) di bawah cross section
  • Bisa memproses beberapa sheet sekaligus
  • Setting elevasi datum
  • Type labelling bisa di tiap perubahan slope atau di tiap pertambahan jarak.
  • Bisa dilakukan checking cross section di excel dengan cara menggambarkan cross section dalam bentuk grafik atau chart secara otomatis.

Contoh hasil plotting…

View original 910 more words

November 2, 2013

[XLS-SVY-05]: Form Excel untuk Perhitungan Pasut dengan Hitung Kwadrat Terkecil

Filed under: Excel, Tukang Ukur — Tags: , , — cadex @ 09:06
Referensi : [XLS-SVY-01]: Prediksi Pasut dengan VBA Excel
Platform : Excel
Lokasi File : download rev-2
download rev-3

Pada post [XLS-SVY-01]: Prediksi Pasut dengan VBA Excel telah dijelaskan teori perhitungan pasang surut metode least square dengan vba excel.

Kali ini akan diuraikan tahapan pengisian pada form excel yang sudah ada program macro (vba) untuk perhitungan prediksi pasang surut (Tidal Prediction)

1. Jalankan file Excel, kemudian set security level ke ‘medium’.
Untuk excel 2003, click menu ‘Tool2’>>’Macro’>>’Security’
Pilih Security ‘Medium’. Untuk excel yang lain silahkan di cari di menu help atau bisa dicari lewat om google.
2. download rev-2 (excel 2003) formnya, kemudian extract zip filenya
3. Setelah buka file hasil download tersebut. Saat ada konfirmasi macro, click ‘Enable Macros
4. Dalam form tersebut sudah ada contoh data hasil pengamatan pasang surut selama 29 hari (1-29 Maret 2008) dengan interval bacaan pada peil scale (rambu ukur) pasang surut tiap 1 jam
Bacaan rambu ukur, dimasukkan dalam satuan meter.
Data ini bisa diganti jumlah harinya, asalkan interval pengamatan adalah 1 (satu) jam

Bagian-bagian dari form perhitungan atau prediksi pasut:

pasut

Urutan pengisian adalah:

1. Isikan informasi lokasi pengamatan, jenis alat yang dipakai dan unit pengukuran di area nomer 1
2. Area Nomer 2 :
-Masukkan di cell [B10] tanggal awal pengamatan.
-Isikan bacaan pengamatan rambu ukur tiap jam di [C10:Z10] dari jam 0:00 sampai jam 23:00
-Isikan pengamatan di tanggal berikutnya di hari ke-2 sampai hari ke-29 sehingga didapat data pengamatan pasang surut sebanyal 29 hari x 24 bacaan/hari = 696 bacaan
3. Tekan Ctr+r sehingga muncul:
image

[$C$10:$Z$38]: Data pengamatan pasang surut
[$G$67:$G$75]: Periode untuk masing-masing 9 konstituent.
kemudian click ‘OK’

4. Hasil perhitungan di Area nomer 4:
image
5. Grafik di Area nomer 5 akan terbentuk secara otomatis. Grafik ini terdiri dari 4 Series yaitu:
1. Posisi Mean Sea Level
2. Actual Pengamatan Pasang Surut
3. Prediksi Pasang Surut berdasarkan rumus harmonic dengan 9 parameters (9 konstituent)
4. Grafik beda elevasi antar hasil hitungan (prediksi) dan actual
6. Tabel di area nomer 6:
image

Update 15 November 2012:

Untuk memfasilitasi pengunjung yang menginginkan hitungan untuk data pengamatan 15hari, silahkan di download rev-2.

Cara penggunaannya sama dengan sebelumnya, hanya saja yang membedakan adalah pilihan blok data pasutnya menjadi [$C$10:$Z$24]. Dengan cara yang sama pula silahkan dicoba jika datanya lebih dari 29 hari.

Mohon tanggapannya jika ada error atau salah hitung

 

Update 1 September 2012:

Revisi terbaru (download rev-3) menggunakan macro di excel 2007. Pada versi ini data input dan output dimasukkan dalam sheet yang berbeda.

Sheet [Input] hanya berisi informasi data pengukuran elevasi dan informasi pendukung lainnya seperti lokasi pengamatan.

image

Sheet [Calculation] ada tambahan tombol [Calculate] untuk memulai menghitung setelah data dimasukkan secara lengkap di sheet [Input]

image

Tampilan grafik dirubah sedikit dengan menampilkan label Mean Sea Level (MSL) dan label deviasi antara harga perhitungan dan pengamatan yang mempunyai deviasi terbesar.

image

==selamat mencoba==

September 9, 2013

[XLS-PMG-06]:Fungsi Terbilang di Excel Tanpa Macro (Versi Mega Formula) Rev.02

Filed under: Excel — Tags: — cadex @ 08:57

Referensi

:

[XLS-PMG-02]: Rumus Terbilang di Excel (Tanpa Macro/VBA)

Platform

:

Excel 2007

Lokasi File

:

download

Pada posting [XLS-PMG-02]: Rumus Terbilang di Excel (Tanpa Macro/VBA), diuraikan langkah membuat fungsi terbilang dengan menggunakan fasilitas ‘named range’. Pada posting tersebut menggunakan 21 (dua puluh satu) named ranges.

Kelemahan dari fungsi terbilang di posting sebelumnya adalah mengharuskan user untuk selalu mengubah “named range” [Angka], jika angka yang akan disebutkan terbilangnya ada di sheet lain.

Misalkan angka yang akan disebut terbilangnya ada di sheet [SheetBaru] Range [B1], maka range [Angka] yang sebelumnya refer ke

[Angka]=TEXT(terbilang!A18,REPT(“0″,9)&”.00″) dirubah menjadi

[Angka]=TEXT(SheetBaru!B1,REPT(“0″,9)&”.00″)

Posting kali ini akan digunakan cara baru yaitu menggunakan satu formula yang panjang (Mega Formula) dan dua “named range” yang bersifat tetap atau konstan yang tidak perlu dirubah-rubah lagi jika akan meng-copy formula di sheet lain dalam satu workbook.

Mega Formula menggunakan kombinasi fungsi excel yaitu empat fungsi manipulati text : TEXT(), REPT(), MID(), SUBSTITUTE() dan satu fungsi array : INDEX()

Berikut adalah langkah-langkahnya:

1. Buat 2 (dua) “named range”

Named Range

Refer To

Note

frm

=”000000000″

maksimal angka 999999999 interger (tanpa desimal)

ListHuruf

={“”,”satu”,”dua”,”tiga”,”empat”,”lima”,”enam”,”tujuh”,”delapan”,”sembilan”,”sepuluh”,”sebelas”,”dua belas”,”tiga belas”,”empat belas”,”lima belas”,”enam belas”,”tujuh belas”,”delapan belas”,”sembilan belas”}

  

2. Misal angka yang akan disebut terbilangnya ada di [A2], maka rumus atau formula terbilangnya adalah

Rev.01 update menjadi maximal 12 digit angka bulat

=IF(LEN(INT(A2))>LEN(_frm),”#Maximal 12 digit angka bulat#”,
SUBSTITUTE(
INDEX(ListHuruf,MID(TEXT(A2,_frm),1,1)+1)
&REPT(” ratus “,0+MID(TEXT(A2,_frm),1,3)>99)
&INDEX(ListHuruf,(0+MID(TEXT(A2,_frm),2,2)<20)*MID(TEXT(A2,_frm),2,2)+1)
&INDEX(ListHuruf,(0+MID(TEXT(A2,_frm),2,2)>19)*MID(TEXT(A2,_frm),2,1)+1)
&REPT(” puluh “,0+MID(TEXT(A2,_frm),2,2)>19)
&INDEX(ListHuruf,(0+MID(TEXT(A2,_frm),2,2)>19)*MID(TEXT(A2,_frm),3,1)+1)
&REPT(” milyar “,LEN(A2)>9)

&INDEX(ListHuruf,MID(TEXT(A2,_frm),4,1)+1)
&REPT(” ratus “,0+MID(TEXT(A2,_frm),4,3)>99)
&INDEX(ListHuruf,(0+MID(TEXT(A2,_frm),5,2)<20)*MID(TEXT(A2,_frm),5,2)+1)
&INDEX(ListHuruf,(0+MID(TEXT(A2,_frm),5,2)>19)*MID(TEXT(A2,_frm),5,1)+1)
&REPT(” puluh “,0+MID(TEXT(A2,_frm),5,2)>19)
&INDEX(ListHuruf,(0+MID(TEXT(A2,_frm),5,2)>19)*MID(TEXT(A2,_frm),6,1)+1)
&REPT(” juta “,(0+MID(TEXT(A2,_frm),4,3)>0))

&SUBSTITUTE(INDEX(ListHuruf,MID(TEXT(A2,_frm),7,1)+1)
&REPT(” ratus “,0+MID(TEXT(A2,_frm),7,3)>99)
&INDEX(ListHuruf,(0+MID(TEXT(A2,_frm),8,2)<20)*MID(TEXT(A2,_frm),8,2)*(A2>=2000)+1)
&INDEX(ListHuruf,(0+MID(TEXT(A2,_frm),8,2)>19)*MID(TEXT(A2,_frm),8,1)*(A2>=2000)+1)
&REPT(” puluh “,0+MID(TEXT(A2,_frm),8,2)>19)
&INDEX(ListHuruf,(0+MID(TEXT(A2,_frm),8,2)>19)*MID(TEXT(A2,_frm),9,1)+1)
&REPT(“seribu “,(A2<2000)*(LEN(A2)=4))
&REPT(” ribu “,(A2>=2000)*(0+MID(TEXT(A2,_frm),7,3)>0)), “satu ribu”,”seribu”)

&INDEX(ListHuruf,MID(TEXT(A2,_frm),10,1)+1)
&REPT(” ratus “,0+MID(TEXT(A2,_frm),10,3)>99)
&INDEX(ListHuruf,(0+MID(TEXT(A2,_frm),11,2)<20)*MID(TEXT(A2,_frm),11,2)+1)
&INDEX(ListHuruf,(0+MID(TEXT(A2,_frm),11,2)>19)*MID(TEXT(A2,_frm),11,1)+1)
&REPT(” puluh “,0+MID(TEXT(A2,_frm),11,2)>19)
&INDEX(ListHuruf,(0+MID(TEXT(A2,_frm),11,2)>19)*MID(TEXT(A2,_frm),12,1)+1),
“satu ratus”,”seratus”
))

Code for spelling number to English :

=IF(LEN(INT(A3))>LEN(_frm),”#Maximal 12 digit#”,
INDEX(ListNumber,MID(TEXT(A3,_frm),1,1)+1)
&REPT(” hundred “,0+MID(TEXT(A3,_frm),1,3)>99)
&INDEX(ListNumber,(0+MID(TEXT(A3,_frm),2,2)<20)*MID(TEXT(A3,_frm),2,2)+1)
&INDEX(ListNumber_,(0+MID(TEXT(A3,_frm),2,2)>=20)*(0+MID(TEXT(A3,_frm),2,2)<=59)*(MID(TEXT(A3,_frm),2,1)))
&INDEX(ListNumber,(0+MID(TEXT(A3,_frm),2,2)>59)*MID(TEXT(A3,_frm),2,1)+1)
&REPT(“ty”,0+MID(TEXT(A3,_frm),2,2)>59)
&REPT(“-“,0+MID(TEXT(A3,_frm),3,1)>0)
&INDEX(ListNumber,(0+MID(TEXT(A3,_frm),2,2)>=20)*MID(TEXT(A3,_frm),3,1)+1)
&REPT(” billion “,LEN(A3)>9)

&INDEX(ListNumber,MID(TEXT(A3,_frm),4,1)+1)
&REPT(” hundred “,0+MID(TEXT(A3,_frm),4,3)>99)
&INDEX(ListNumber,(0+MID(TEXT(A3,_frm),5,2)<20)*MID(TEXT(A3,_frm),5,2)+1)
&INDEX(ListNumber_,(0+MID(TEXT(A3,_frm),5,2)>=20)*(0+MID(TEXT(A3,_frm),5,2)<=59)*(MID(TEXT(A3,_frm),5,1)))
&INDEX(ListNumber,(0+MID(TEXT(A3,_frm),5,2)>59)*MID(TEXT(A3,_frm),5,1)+1)
&REPT(“ty”,0+MID(TEXT(A3,_frm),5,2)>59)
&REPT(“-“,0+MID(TEXT(A3,_frm),6,1)>0)
&INDEX(ListNumber,(0+MID(TEXT(A3,_frm),5,2)>=20)*MID(TEXT(A3,_frm),6,1)+1)
&REPT(” million “,(0+MID(TEXT(A3,_frm),4,3)>0))

&INDEX(ListNumber,MID(TEXT(A3,_frm),7,1)+1)
&REPT(” hundred “,0+MID(TEXT(A3,_frm),7,3)>99)
&INDEX(ListNumber,(0+MID(TEXT(A3,_frm),8,2)<20)*MID(TEXT(A3,_frm),8,2)+1)
&INDEX(ListNumber_,(0+MID(TEXT(A3,_frm),8,2)>=20)*(0+MID(TEXT(A3,_frm),8,2)<=59)*(MID(TEXT(A3,_frm),8,1)))
&INDEX(ListNumber,(0+MID(TEXT(A3,_frm),8,2)>59)*MID(TEXT(A3,_frm),8,1)+1)
&REPT(“ty”,0+MID(TEXT(A3,_frm),8,2)>59)
&REPT(“-“,0+MID(TEXT(A3,_frm),9,1)>0)
&INDEX(ListNumber,(0+MID(TEXT(A3,_frm),8,2)>=20)*MID(TEXT(A3,_frm),9,1)+1)
&REPT(” thousand “,0+MID(TEXT(A3,_frm),7,3)>0)

&INDEX(ListNumber,MID(TEXT(A3,_frm),10,1)+1)
&REPT(” hundred “,(0+MID(TEXT(A3,_frm),10,3))>99)
&INDEX(ListNumber,(0+MID(TEXT(A3,_frm),11,2)<20)*MID(TEXT(A3,_frm),11,2)+1)
&INDEX(ListNumber_,(0+MID(TEXT(A3,_frm),11,2)>=20)*(0+MID(TEXT(A3,_frm),11,2)<=59)*(MID(TEXT(A3,_frm),11,1)))
&INDEX(ListNumber,(0+MID(TEXT(A3,_frm),11,2)>59)*MID(TEXT(A3,_frm),11,1)+1)
&REPT(“ty”,0+MID(TEXT(A3,_frm),11,2)>59)
&REPT(“-“,0+MID(TEXT(A3,_frm),12,1)>0)
&INDEX(ListNumber,(0+MID(TEXT(A3,_frm),11,2)>=20)*MID(TEXT(A3,_frm),12,1)+1)
)

Silahkan dicoba, jika ada yang salah penyebutan angkanya tolong aku diberitahu ya…

-zainul-

May 29, 2013

[XLS-SVY-21]: Menampilkan Cross Section 3D dengan Chart Excel

Filed under: Excel, Tukang Ukur — Tags: , — cadex @ 09:06

 

Referensi :  
Platform : Excel 2007
Lokasi file : download

Sebenarnya di Excel sudah menyediakan type "Surface Chart" yang bisa menampilkan grafik dengan data input 3 dimensi (XYZ) termasuk kemampuan untuk merubah properties sudut putarnya. Surface Chart bisa menampilkan grafik atau surface 3D jika nilai data X dan Y mempunyai nilai increment yang tetap atau dengan sistem grid karena dalam Surface Chart X dan Y tidak ditampilkan sebagai data numeric sehingga bukan nilai actual X dan Y itu sendiri.

Berikut contoh input data untuk Surface Chart dan tampilan hasilnya dalam chart:

image

Data di atas mempunyai nilai X dan Y yang tetap.

Untuk menampilkan data cross section dimana data X dan Y nya tidak teratur, seharusnya ada type chart tambahan yaitu 3D XYZ (scattered) tetapi sampai saat ini saya belum menemukan type chart yang dimaksud. Agar tampilan cross section 2D dapat ditampilkan 3D, maka data XYZ cross section dimanipulasi dengan matrik rotasi kemudian diplotkan di grafik XY (Scattered).

Format data cross section yang dipakai untuk simulasi ini adalah sama dengan data yang pernah dibahas di posting [XLS-SVY-007]: Plotting Cross Section dari Excel ke AutoCAD dan [XLS-SVY-13]: Plotting Cross Section dari Excel ke AutoCAD Versi 1.1. Dalam contoh cross section terlampir terdapat 3 buah cross section 2D yang akan diplot menjadi cross 3D. Nilai koordinat X diambil dari nama station dalam bentuk numeric. Misal untuk station 0+000 dan 100+000, maka koordinat X nya berturut-turut adalah 0 dan 100. Sedangkan koordinat Y mengacu jarak dari centerline atau offset dan nilai Z mengacu ke elevasi.

Berikut adalah cuplikan data yang dimaksud berikut dengan Chart 2D :

Station/Sheet Data & Chart 2D
0 image
50 image
100 image

Tampilan data dan 3D cross :

image

Semua proses pembentukan tabel dan perhitungan menggunakan fungsi formula excel tanpa menggunakan macro.

Uratan perhitungan adalah sebagai berikut:

1. Menghitung jumlah record dari sheet yang akan ditamplikan di chart 3D   image
 

[A3:A5]

List nama sheet dari masing-masing data 2D cross section. Diisi dengan numeric

  [B3] =COUNT(INDIRECT("’"&A3&"’!B1:B300"))
menghitung jumlah record di sheet A3. Maksimal record 300
Copy rumus [B3] ke bawah untuk menghitung record di sheet lainnya
  [C3:C5] cell bantu untuk menunjukkan lokasi perpindahan cross di table baru. Tabel baru adalah tabel gabungan dari beberapa data cross
  [B1] =SUM(B3:B5)
jumlah record di tabel baru
  [C1] =COUNT(A3:A50)
jumlah sheet yang akan ditampilkan
2. Menggabungkan record dalam satu tabel baru   image[E3]=IF(ROWS($E$2:E2)<=$B$1,ROWS($E$2:E2))
[F3]=LOOKUP(E3,$C$3:$C$5,$A$3:$A$5)
[G3]=OFFSET(INDIRECT("’"&$F3&"’!$B$1"),COUNTIF($F$3:$F3,$F3),)
[H3]=OFFSET(INDIRECT("’"&$F3&"’!$c$1"),COUNTIF($F$3:$F3,$F3),)

[E3] membuat nomer urut record di tabel baru. Bernilai FALSE jika nomer urut melebihi dari hitungan jumlah record di $B$1
[F3] menampilkan angka STA (koordinat X), berdasarkan cell bantu di cell [$C$3:$C$5]
[G3] menambil nilai offset (Y) dari berdasarkan nama sheet di cell [F3]
[H3] menambil nilai offset (Z) dari berdasarkan nama sheet di cell [F3]
copy rumus [E3:H3] ke bawah sampai nilai di [E3]=FALSE

3. Setting Matriks Rotasi   image
  [K3],[K4] dan [K5] Masukkan sudut rotasi dalam satuan derajat
  [L3] =RADIANS(K3)
  [L4] =RADIANS(K4)
  [L5] =RADIANS(K5)
    Buat "Named Range" rx, ry dan rz yang mengacu ke range [L3], [L4] dan [L5]
  [J9] =COS(ry)*COS(rz)
  [J10] =-COS(ry)*SIN(rz)
  [J11] =SIN(ry)
     
  [K9] =COS(rx)*SIN(rz)+SIN(rx)*SIN(ry)*COS(rz)
  [K10] =COS(rx)*COS(rz)-SIN(rx)*SIN(ry)*SIN(rz)
  [K11] =-SIN(rx)*COS(ry)
     
  [L9] =SIN(rx)*SIN(rz)-COS(rx)*SIN(ry)*COS(rz)
  [L10] =SIN(rx)*COS(rz)+COS(rx)*SIN(ry)*SIN(rz)
  [L11] =COS(rx)*COS(ry)
4. Perkalian Matrix Asal dengan Matrix Rotasi   Matrix Asal adalah matrix yang dibentuk dari tabel baru dengan mangambil nilai X,Y dan Z. Jumlah baris di matrix adalah=banyaknya record=[B1], sedangkan jumlah kolomnya=3. Dari contoh di atas, Matrix asalah adalah dimulai dari F3, dengan jumlah baris sebanyak B1 ke bawah dan lebar ke kanan 3 kolom atau kalo dinyatakan dalam rumus excel adalah =OFFSET($F$3,,,$B$1,3).
Formula bawah ini named range dan formula yang dipakai untuk perhitungan perkalian matrix:
  _3dCross =OFFSET($F$3,,,$B$1,3)
matrix asal
  _2DPlot =MMULT(_3dCross,TRANSPOSE($J$9:$L$10))
perkalian matrix asal ke matrix rotasi. Hasil dari perkalian ini adalah matrix dengan dimensi (n x 2), n= jumlah record dan 2 adalah absis x dan y yang akan diplot di chart 2D xy scattered
5. Setting series untuk chart XY Scattered _x =OFFSET($F$3,,,$B$1)
  _sta =OFFSET($A$3,,,$C$1)
  _xPlot =INDEX(_2DPlot,,1)
  _yPlot =INDEX(_2DPlot,,2)
  __x1 =IF(_x=INDEX(_sta,1),_xPlot,NA())
  __x2 =IF(_x=INDEX(_sta,2),_xPlot,NA())
  __x3 =IF(_x=INDEX(_sta,3),_xPlot,NA())
  __y1 =IF(_x=INDEX(_sta,1),_yPlot,NA())
  __y2 =IF(_x=INDEX(_sta,2),_yPlot,NA())
  __y3 =IF(_x=INDEX(_sta,3),_yPlot,NA())

Rangkuman named range yang dipakai dalam perhitungan dan chart adalah

image

Untuk setting chart dan bentuk box, silahkan dipelajari lebih lanjut dari file terlampir.

==selamat mencoba==

May 28, 2013

[XLS-SVY-02]: Catatan Rumus Excel untuk Juru Ukur (Bagian #1)

Filed under: Excel, Tukang Ukur — Tags: — cadex @ 12:04
Referensi :  
Platform : Microsoft Excel
Lokasi File :  

Note: Semua rumus yang dipakai menggunakan setting microsoft excel pemisah desimal adalah titik "."

Konversi sudut

1. Radian(misal di A1) ke Derajat =DEGREES(A1)

2. Derajat(misal di B1) ke Radian =RADIANS(B1)

3. Derajat (misal di C8) ke Derajat-Menit-Detik

Derajat =TRUNC(C8)

Menit =TRUNC((C8-TRUNC(C8))*60)

Detik =3600*(C8-TRUNC(C8))-60*TRUNC((C8-TRUNC(C8))*60)

3.a. Derajat-Menit-Detik ke Desimal

Misal nilai derajat, menit dan detik disimpan masing-masing di A1, B1, dan C1 dan hasil konversi ke desimal adalah di D1, maka rumus konevrsinya adalah

D1=A1+B1/60+B1/3600 atau D1=SUMPRODUCT(A1:C1/{1,60,3600})

4. Derajat (misal di B1) ke Derajat-Menit-Detik dengan ‘Format Cell’

Misal hasilnya akan ditampilkan di C1, maka di C1=B1/24

1. Di cell C1, tekan CTRL+1
2. Pada ‘Format Cells’, pilih ‘Custom’
3. Ketik ‘Custom Type’ [h]-m-s.000
4. Hasil sudut ditampilkan dalam format derajat-menit-detik. Angka untuk detik ditampilkan dalam 3 (tiga) desimal

5. Konversi format derajat, menit dan detik ke sudut d.mmss

Salah satu format sudut yang didapat hasil download Total Station adalah format d.mmss. Format sudut ini juga dipakai di Autodesk Civil 3D Survey pada saat proses perhitungan least square atau perhitungan hasil pengukuran.

Contoh:

sudut 30 derajat, 1 menit, 1 detik, dalam format d.mmss akan ditulis: 30.0101

sudut 333 derajat, 0 menit, 2.34 detik, dalam format d.mmss akan ditulis : 333.00234

Misal kolom sudut derajat,menit dan detik ada di A1, B1 dan C1, maka rumus sudut dalam format d.mmss adalah

D1=(A1 & "." & TEXT(B1,"00") & TEXT(C1*100,"00"))

6. Rumus untuk merubah type sudut d.mmss ke derajat,menit dan detik adalah:

jika E1, F1 dan G1 adalah derajat, menit dan detik hasil konversi, maka rumusnya adalah:

E1=–LEFT(TEXT(D1,"000.000000"),3)

F1=–MID(TEXT(D1,"000.000000"),5,2)

G1=–RIGHT(TEXT(D1,"000.000000"),4)/100

7. Rumus untuk merubah sudut d.mmss ke desimal

Jika A1 adalah sudut dalam format d.mmss dan B1 adalah hasil konversi sudut dalam desimal:

B1=SUMPRODUCT(MID(TEXT(A1,"000.000000"),{1,5,7},{3,2,4})/{1,60,360000})

Hitung azimut dari dua koordinat

Jika Koordinat (X1,Y1) titik 1 adalah D19,E19
dan Koordinat (X2,Y2) titik 2 adalah D21,E21

maka rumus azimuth diexcel dalam satuan derajat adalah
=DEGREES(ATAN2((E21-E19),(D21-D19)))+IF(ATAN2((E21-E19),(D21-D19))<0,360)

Pengurangan Sudut

Misal bacaan sudut ke titik#1 adalah A1, dan bacaan sudut ke titik#2 adalah B1, maka besar sudut dari A1 ke B1 adalah

=B1-A1+IF(A1>B1,360)

Penambahan Sudut

=A1+B1-IF(A1+B1>360,360)

<<bersambung>>

May 26, 2013

[GEN-SVY-02]: Matriks Rotasi 3 Dimensi

Filed under: Map, Tukang Ukur — Tags: , — cadex @ 11:53
Referensi : Rotation Matrix
Platform :
Lokasi File : download penurunan rumus matriks rotasi

 

Matriks rotasi di bidang pemetaan banyak dipakai untuk transformasi koordinat, khususnya transformasi koordinat 3D. Sedangkan untuk aplikasi di luar pemetaan banyak dipakai untuk visualisasi 3D dan pemograman 3D.

Posting kali ini menguraikan pembuktian / menurunkan persamaan matriks rotasi dalam sistem koordinat 3 (tiga) dimensi:

image Koordinat P (Xp, Yp, Zp) akan dirotasi dengan urutan rotasi berturut-turut dengan sumbu putar di sumbu-X, sumbu-Y dan sumbu-Z

Matrik rotasi menggunakan aturan sistem aturan tangan kanan. Dalam sistem aturantangan kanan, sudut positif adalah searah dengan lipatan jari tangan apabila ibu jari tangan kanan diarahkan ke arah positif koordinat. Sudut rotasi dengan sumbu putar sumbu-x, sumbu-y dan sumbu-z didefinisikan berturut-turut sebagai ω, φ dan κ.

Proses penurunan matriks rotasi mengikuti urutan sebagai berikut:

  1. Rotasi terhadap sumbu-X (ω), kemudian
  2. Rotasi terhadap sumbu-Y (φ), kemudian
  3. Rotasu terhadap sumbu-Z (κ)

1. Rotasi terhadap sumbu-x (ω)

image image

2. Rotasi terhadap sumbu-y (φ)

image image

3. Rotasi terhadap sumbu-z (κ)

image image

image

Penerapan matriks rotasi ini akan dibahas pada posting berikutnya.

==semoga bermanfaat==

Older Posts »

The Shocking Blue Green Theme. Blog at WordPress.com.

Follow

Get every new post delivered to your Inbox.

Join 787 other followers