Saya mendapatkan data survey hasil pengukuran jaring trilateration kombinasi dengan triangulation dengan menggunakan total station. Data tersebut terdiri dari informasi tentang tempat berdiri alat, tinggi alat, tinggi target, target, bacaan sudut horisontal, bacaan sudut vertikal, jarak datar dan jarak miring.
Tulisan kali ini akan saya fokuSkan bagaimana cara menghitung sudut horisontal dan jarak horisontal (HD).
A. Menghitung rata-rata dan standar deviasi sudut horisontal.
Format yang saya pakai untuk menghitung sudut adalah sebagai berikut :
| [O5] |
=E5 |
Nama Target Backsight (BS) |
| [P5] |
=A5 |
Kedudukan Instrument atau station (STN) |
| [Q5] |
=E6 |
Nama Target Foresight (FS) |
| [R5] |
=F5+G5/60+H5/3600 |
Konversi sudur derajat, menit,detik ke derajat desimal, copy rumus ini sampai ke [R12] |
| [S6] |
=IF(D6="B",R6-R5+IF(R5>R6,360),R5-R6+IF(R6>R5,360)) |
menghitung sudut horisontal yaitu bacaan sudut FS dikurangi bacaan sudut BS.
Penting!!!:
Rumus ini berlaku jika urutan pengukuran sudutnya adalah B(Backsight)-B(Foresight)-LB(Foresight)-LB(Backsight)
untuk urutan B(Backsight)-LB(Backsight)-LB(Foresight)-B(Foresight) silahkan dilihat di file attachment. |
| [S8],[S10],[S12] |
|
dicopy dari rumus di [S6] |
| [T6] |
=S6/24 |
konversi sudut derajat desimal ke derajat-menit-detik dengan menggunakan format time di excel.
set format number di [T6] menjadi [h]° mm’ ss\"
untuk menampilkan symbol derajat: tekan tombol ALT, tahan tombol ALT kemudian tekan angka 176 di numeric pad, kemudian lepaskan tombol ALT.
Jika menggunakan laptop, numeric pad akan aktif jika tombol ‘number lock’ diaktifkan. Posisi tombol akan berbeda tergantung merk dan type laptop. Contoh saya menggunakan laptop hp pavilium dv3, tombol number lock diaktifkan dengan menekan bersama-sama tombol Fn+shitf+numlk.
Penting!!!:
Rumus menggunakan format jam ini berlaku jika nilai sudutnya selalu positif |
| [T8],[T10],[T12] |
|
copy rumus dari [T6] |
| [U5] |
=AVERAGE(T6:T12) |
menghitung sudut rata-rata |
| [V5] |
=STDEV(T6:T12) |
menghitung standar deviasi |
| |
|
copy rumus [U5:V5] ke [U14:V14] |
B. Menghitung rata-rata dan standard deviasi jarak horisontal
Format yang saya pakai untuk menghitung jarak adalah:
sebelum mulai perhitungan jarak, perlu didefinisikan ID penggal jarak. Jarak rata2 dan standar deviasi akan dihitung jika mempunya id yang sama. Jika pengukuran jarak dimulai dari station (STN) BMS1 dan target (FS) adalah BMS2 maka ID nya harus sama dengan pengkuran sebaliknya STN di BMS2 dan FS di BMS1
List ID penggal jarak didefinikan di kolom AC, AD dan AE. Perlu diperhatikan bahwa nama station(STN) dan foresight(FS) harus sama persis, jika tidak maka akan terjadi kesalah perhitungan di rata-rata dan standard deviasi. “BMS1” tidak sama dengan “BMS 1”.
Tips: saat pengolahan data seperti ini, untuk menghindari salah hitung sebaiknya nama (id) titik berupa angka saja tanpa ada karakter.
| [AA5] |
=SUM((((X5=$AD$5:$AD$13)*(Y5=$AE$5:$AE$13)+(Y5=$AD$5:$AD$13)*(X5=$AE$5:$AE$13))=1)*$AC$5:$AC$13) |
Formula array: setelah menulis rumusnya, akhir dengan (CTRL+SHIFT+ENTER)
Berfungsi untuk mencari ID penggal garis dari list ID yang sudah didefinisikan di kolom [AC], [AD] dan [AE] |
| [AA6:AA12] |
copy rumus dari [AA5] |
|
| [AF5] |
=AVERAGE(IF($AA$5:$AA$89=AC5,$Z$5:$Z$89)) |
Formula array: untuk menghitung rata-rata di penggal garis sesuai dengan id di [AC5] |
| [AG5] |
=STDEV(IF($AA$5:$AA$89=AC5,$Z$5:$Z$89)) |
Formula array: menghitung standar deviasi |
| [AF6:AG13] |
copy [AF5:AG5] |
|
==silahkan dicoba==
